/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.209 - (show annotations) (download)
Thu Feb 20 20:32:14 2014 UTC (3 years, 5 months ago) by tomwij
Branch: MAIN
Changes since 1.208: +27 -10 lines
Preparation for version bump by updating 9999 ebuild, small USE flag and medium configure parameter changes.

(Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.208 2014/01/30 16:40:36 tomwij Exp $
4
5 EAPI="5"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM="git-r3"
10
11 if [ "${PV%.9999}" != "${PV}" ] ; then
12 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
13 else
14 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
15 fi
16 fi
17
18 inherit eutils multilib autotools toolchain-funcs flag-o-matic virtualx ${SCM}
19
20 MY_PV="${PV/_/-}"
21 MY_PV="${MY_PV/-beta/-test}"
22 MY_P="${PN}-${MY_PV}"
23
24 DESCRIPTION="VLC media player - Video player and streamer"
25 HOMEPAGE="http://www.videolan.org/vlc/"
26 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
27 SRC_URI=""
28 elif [[ "${MY_P}" == "${P}" ]]; then
29 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.xz"
30 else
31 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.xz"
32 fi
33
34 LICENSE="LGPL-2.1 GPL-2"
35 SLOT="0/5-7" # vlc - vlccore
36
37 if [ "${PV%9999}" = "${PV}" ] ; then
38 KEYWORDS="~amd64 ~arm ~ppc -sparc ~x86 ~amd64-fbsd ~x86-fbsd"
39 else
40 KEYWORDS=""
41 fi
42
43 IUSE="a52 aalib alsa altivec atmo +audioqueue avahi +avcodec
44 +avformat bidi bluray cdda cddb chromaprint dbus dc1394 debug
45 directfb directx dts dvb +dvbpsi dvd dxva2 elibc_glibc egl +encode faad fdk
46 fluidsynth +ffmpeg flac fontconfig +gcrypt gles1 gles2 gme gnome gnutls
47 growl httpd ieee1394 ios-vout jack jpeg kate kde libass libcaca libnotify
48 libsamplerate libtiger linsys libtar lirc live lua +macosx
49 +macosx-audio +macosx-dialog-provider +macosx-eyetv +macosx-quartztext
50 +macosx-qtkit +macosx-vout matroska media-library mmx modplug mp3 mpeg
51 mtp musepack ncurses neon ogg omxil opencv opengl optimisememory opus
52 png +postproc projectm pulseaudio +qt4 qt5 rdp rtsp run-as-root samba
53 schroedinger sdl sdl-image sftp shout sid skins speex sse svg +swscale
54 taglib theora tremor truetype twolame udev upnp vaapi v4l vcdx vdpau
55 vlm vnc vorbis vpx wma-fixed +X x264 +xcb xml xv zvbi"
56
57 RDEPEND="
58 !<media-video/ffmpeg-1.2:0
59 dev-libs/libgpg-error:0
60 net-dns/libidn:0
61 >=sys-libs/zlib-1.2.5.1-r2:0[minizip]
62 virtual/libintl:0
63 a52? ( >=media-libs/a52dec-0.7.4-r3:0 )
64 aalib? ( media-libs/aalib:0 )
65 alsa? ( >=media-libs/alsa-lib-1.0.24:0 )
66 avahi? ( >=net-dns/avahi-0.6:0[dbus] )
67 avcodec? ( virtual/ffmpeg:0 )
68 avformat? ( virtual/ffmpeg:0 )
69 bidi? ( >=dev-libs/fribidi-0.10.4:0 )
70 bluray? ( >=media-libs/libbluray-0.3.0:0 )
71 cddb? ( >=media-libs/libcddb-1.2.0:0 )
72 chromaprint? ( >=media-libs/chromaprint-0.6:0 )
73 dbus? ( >=sys-apps/dbus-1.0.2:0 )
74 dc1394? ( >=sys-libs/libraw1394-2.0.1:0 >=media-libs/libdc1394-2.1.0:2 )
75 directfb? ( dev-libs/DirectFB:0 sys-libs/zlib:0 )
76 dts? ( media-libs/libdca:0 )
77 dvbpsi? ( >=media-libs/libdvbpsi-0.2.1:0 )
78 dvd? ( media-libs/libdvdread:0 >=media-libs/libdvdnav-0.1.9:0 )
79 egl? ( virtual/opengl:0 )
80 elibc_glibc? ( >=sys-libs/glibc-2.8:2.2 )
81 faad? ( >=media-libs/faad2-2.6.1:0 )
82 fdk? ( media-libs/fdk-aac:0 )
83 flac? ( media-libs/libogg:0 >=media-libs/flac-1.1.2:0 )
84 fluidsynth? ( >=media-sound/fluidsynth-1.1.2:0 )
85 fontconfig? ( media-libs/fontconfig:1.0 )
86 gcrypt? ( >=dev-libs/libgcrypt-1.2.0:0 )
87 gles1? ( virtual/opengles:0 )
88 gles2? ( virtual/opengles:0 )
89 gme? ( media-libs/game-music-emu:0 )
90 gnome? ( gnome-base/gnome-vfs:2 dev-libs/glib:2 )
91 gnutls? ( >=net-libs/gnutls-3.0.20:0 )
92 ieee1394? ( >=sys-libs/libraw1394-2.0.1:0 >=sys-libs/libavc1394-0.5.3:0 )
93 ios-vout? ( virtual/opengl:0 )
94 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1:0 )
95 jpeg? ( virtual/jpeg:0 )
96 kate? ( >=media-libs/libkate-0.3.0:0 )
97 libass? ( >=media-libs/libass-0.9.8:0 media-libs/fontconfig:1.0 )
98 libcaca? ( >=media-libs/libcaca-0.99_beta14:0 )
99 libnotify? ( x11-libs/libnotify:0 x11-libs/gtk+:2 x11-libs/gdk-pixbuf:2 dev-libs/glib:2 )
100 libsamplerate? ( media-libs/libsamplerate:0 )
101 libtar? ( >=dev-libs/libtar-1.2.11-r3:0 )
102 libtiger? ( >=media-libs/libtiger-0.3.1:0 )
103 linsys? ( >=media-libs/zvbi-0.2.28:0 )
104 lirc? ( app-misc/lirc:0 )
105 live? ( >=media-plugins/live-2011.12.23:0 )
106 lua? ( >=dev-lang/lua-5.1:0 )
107 macosx-vout? ( virtual/opengl:0 )
108 matroska? ( >=dev-libs/libebml-1.0.0:0= >=media-libs/libmatroska-1.0.0:0= )
109 modplug? ( >=media-libs/libmodplug-0.8.8.1:0 )
110 mp3? ( media-libs/libmad:0 )
111 mpeg? ( >=media-libs/libmpeg2-0.3.2:0 )
112 mtp? ( >=media-libs/libmtp-1.0.0:0 )
113 musepack? ( >=media-sound/musepack-tools-444:0 )
114 ncurses? ( sys-libs/ncurses:5[unicode] )
115 ogg? ( media-libs/libogg:0 )
116 opencv? ( >media-libs/opencv-2.0:0 )
117 opengl? ( virtual/opengl:0 >=x11-libs/libX11-1.3.99.901:0 )
118 opus? ( >=media-libs/opus-1.0.3:0 )
119 png? ( media-libs/libpng:0= sys-libs/zlib:0 )
120 postproc? ( || ( >=media-video/ffmpeg-1.2:0= media-libs/libpostproc:0 ) )
121 projectm? ( media-libs/libprojectm:0 media-fonts/dejavu:0 )
122 pulseaudio? ( >=media-sound/pulseaudio-0.9.22:0 )
123 qt4? ( >=dev-qt/qtgui-4.6.0:4 >=dev-qt/qtcore-4.6.0:4 )
124 qt5? ( >=dev-qt/qtgui-5.1.0:5 >=dev-qt/qtcore-5.1.0:5 dev-qt/qtwidgets:5 )
125 rdp? ( net-misc/freerdp:0= )
126 samba? ( || ( >=net-fs/samba-3.4.6:0[smbclient] >=net-fs/samba-4.0.0:0[client] ) )
127 schroedinger? ( >=media-libs/schroedinger-1.0.10:0 )
128 sdl? ( >=media-libs/libsdl-1.2.10:0
129 sdl-image? ( >=media-libs/sdl-image-1.2.10:0 sys-libs/zlib:0 ) )
130 sftp? ( net-libs/libssh2:0 )
131 shout? ( media-libs/libshout:0 )
132 sid? ( media-libs/libsidplay:2 )
133 skins? ( x11-libs/libXext:0 x11-libs/libXpm:0 x11-libs/libXinerama:0 )
134 speex? ( media-libs/speex:0 )
135 svg? ( >=gnome-base/librsvg-2.9.0:2 )
136 swscale? ( virtual/ffmpeg:0 )
137 taglib? ( >=media-libs/taglib-1.6.1:0 sys-libs/zlib:0 )
138 theora? ( >=media-libs/libtheora-1.0_beta3:0 )
139 tremor? ( media-libs/tremor:0 )
140 truetype? ( media-libs/freetype:2 virtual/ttf-fonts:0
141 !fontconfig? ( media-fonts/dejavu:0 ) )
142 twolame? ( media-sound/twolame:0 )
143 udev? ( >=virtual/udev-142:0 )
144 upnp? ( net-libs/libupnp:0 )
145 v4l? ( media-libs/libv4l:0 )
146 vaapi? ( x11-libs/libva:0 virtual/ffmpeg[vaapi] )
147 vcdx? ( >=dev-libs/libcdio-0.78.2:0 >=media-video/vcdimager-0.7.22:0 )
148 vdpau? ( >=x11-libs/libvdpau-0.6:0 !<media-video/libav-9.11 )
149 vnc? ( >=net-libs/libvncserver-0.9.9:0 )
150 vorbis? ( media-libs/libvorbis:0 )
151 vpx? ( media-libs/libvpx:0 )
152 X? ( x11-libs/libX11:0 )
153 x264? ( >=media-libs/x264-0.0.20090923:0= )
154 xcb? ( >=x11-libs/libxcb-1.6:0 >=x11-libs/xcb-util-0.3.4:0 >=x11-libs/xcb-util-keysyms-0.3.4:0 )
155 xml? ( dev-libs/libxml2:2 )
156 zvbi? ( >=media-libs/zvbi-0.2.25:0 )
157 "
158
159 DEPEND="${RDEPEND}
160 kde? ( >=kde-base/kdelibs-4:4 )
161 xcb? ( x11-proto/xproto:0 )
162 app-arch/xz-utils:0
163 dev-lang/yasm:0
164 >=sys-devel/gettext-0.18.3:0
165 virtual/pkgconfig:0
166 "
167
168 REQUIRED_USE="
169 aalib? ( X )
170 bidi? ( truetype )
171 cddb? ( cdda )
172 dvb? ( dvbpsi )
173 dxva2? ( avcodec )
174 egl? ( X )
175 ffmpeg? ( avcodec avformat swscale postproc )
176 fontconfig? ( truetype )
177 gnutls? ( gcrypt )
178 httpd? ( lua )
179 libcaca? ( X )
180 libtar? ( skins )
181 libtiger? ( kate )
182 qt4? ( X !qt5 )
183 qt5? ( X !qt4 )
184 sdl? ( X )
185 skins? ( truetype X ^^ ( qt4 qt5 ) )
186 vaapi? ( avcodec X )
187 vlm? ( encode )
188 xv? ( xcb )
189 "
190
191 S="${WORKDIR}/${MY_P}"
192
193 pkg_setup() {
194 if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
195 if [[ $(gcc-major-version) < 4 || ( $(gcc-major-version) == 4 && $(gcc-minor-version) < 5 ) ]] ; then
196 die "You need to have at least >=sys-devel/gcc-4.5 to build and/or have a working vlc, see bug #426754."
197 fi
198 fi
199 }
200
201 src_unpack() {
202 if [ "${PV%9999}" != "${PV}" ] ; then
203 git-r3_src_unpack
204 else
205 unpack ${A}
206 fi
207 }
208
209 src_prepare() {
210 # Support for Qt5.
211 if use qt5 ; then
212 export UIC="/usr/lib64/qt5/bin/uic"
213 export MOC="/usr/lib64/qt5/bin/moc"
214 fi
215
216 # Remove unnecessary warnings about unimplemented pragmas on gcc for now.
217 # Need to recheck this with gcc 4.9 and every subsequent minor bump of gcc.
218 #
219 # config.h:792: warning: ignoring #pragma STDC FENV_ACCESS [-Wunknown-pragmas]
220 # config.h:793: warning: ignoring #pragma STDC FP_CONTRACT [-Wunknown-pragmas]
221 #
222 # http://gcc.gnu.org/c99status.html
223 if [[ "$(tc-getCC)" == *"gcc"* ]] ; then
224 sed -i 's/ifndef __FAST_MATH__/if 0/g' configure.ac || die
225 fi
226
227 # _FORTIFY_SOURCE is set to 2 by default on Gentoo, remove redefine warnings.
228 sed -i '/_FORTIFY_SOURCE.*, 2,/d' configure.ac || die
229
230 # Bootstrap when we are on a git checkout.
231 if [[ "${PV%9999}" != "${PV}" ]] ; then
232 ./bootstrap
233 fi
234
235 # Make it build with libtool 1.5
236 rm -f m4/lt* m4/libtool.m4 || die
237
238 # We are not in a real git checkout due to the absence of a .git directory.
239 touch src/revision.txt || die
240
241 # Fix build system mistake.
242 epatch "${FILESDIR}"/${PN}-2.1.0-fix-libtremor-libs.patch
243
244 # Patch up incompatibilities and reconfigure autotools.
245 epatch "${FILESDIR}"/${PN}-2.1.0-newer-rdp.patch
246 epatch "${FILESDIR}"/${PN}-2.1.0-libva-1.2.1-compat.patch
247
248 # Fix up broken audio when skipping using a fixed reversed bisected commit.
249 epatch "${FILESDIR}"/${PN}-2.1.0-TomWij-bisected-PA-broken-underflow.patch
250
251 # Disable avcodec checks when avcodec is not used.
252 sed -i 's/^#if LIBAVCODEC_VERSION_CHECK(.*)$/#if 0/' modules/codec/avcodec/fourcc.c || die
253
254 # Don't use --started-from-file when not using dbus.
255 if ! use dbus ; then
256 sed -i 's/ --started-from-file//' share/vlc.desktop.in || die
257 fi
258
259 eautoreconf
260
261 # Disable automatic running of tests.
262 find . -name 'Makefile.in' -exec sed -i 's/\(..*\)check-TESTS/\1/' {} \; || die
263 }
264
265 src_configure() {
266 # Compatibility fix for Samba 4.
267 use samba && append-cppflags "-I/usr/include/samba-4.0"
268
269 # Needs libresid-builder from libsidplay:2 which is in another directory...
270 # FIXME!
271 append-ldflags "-L/usr/$(get_libdir)/sidplay/builders/"
272
273 if use truetype || use projectm ; then
274 local dejavu="/usr/share/fonts/dejavu/"
275 myconf="--with-default-font=${dejavu}/DejaVuSans.ttf \
276 --with-default-font-family=Sans \
277 --with-default-monospace-font=${dejavu}/DejaVuSansMono.ttf
278 --with-default-monospace-font-family=Monospace"
279 fi
280
281 local qt_flag=""
282 if use qt4 || use qt5 ; then
283 qt_flag="--enable-qt"
284 fi
285
286 econf \
287 ${myconf} \
288 --enable-vlc \
289 --docdir=/usr/share/doc/${PF} \
290 --disable-dependency-tracking \
291 --disable-optimizations \
292 --disable-update-check \
293 --enable-fast-install \
294 --enable-screen \
295 $(use_enable a52) \
296 $(use_enable aalib aa) \
297 $(use_enable alsa) \
298 $(use_enable altivec) \
299 $(use_enable atmo) \
300 $(use_enable audioqueue) \
301 $(use_enable avahi bonjour) \
302 $(use_enable avcodec) \
303 $(use_enable avformat) \
304 $(use_enable bidi fribidi) \
305 $(use_enable bluray) \
306 $(use_enable cdda vcd) \
307 $(use_enable cddb libcddb) \
308 $(use_enable chromaprint) \
309 $(use_enable dbus) \
310 $(use_enable directfb) \
311 $(use_enable directx) \
312 $(use_enable dc1394) \
313 $(use_enable debug) \
314 $(use_enable dts dca) \
315 $(use_enable dvbpsi) \
316 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
317 $(use_enable dxva2) \
318 $(use_enable egl) \
319 $(use_enable encode sout) \
320 $(use_enable faad) \
321 $(use_enable fdk fdkaac) \
322 $(use_enable flac) \
323 $(use_enable fluidsynth) \
324 $(use_enable fontconfig) \
325 $(use_enable gcrypt libgcrypt) \
326 $(use_enable gles1) \
327 $(use_enable gles2) \
328 $(use_enable gme) \
329 $(use_enable gnome gnomevfs) \
330 $(use_enable gnutls) \
331 $(use_enable growl) \
332 $(use_enable httpd) \
333 $(use_enable ieee1394 dv1394) \
334 $(use_enable ios-vout ios-vout2) \
335 $(use_enable jack) \
336 $(use_enable jpeg) \
337 $(use_enable kate) \
338 $(use_with kde kde-solid) \
339 $(use_enable libass) \
340 $(use_enable libcaca caca) \
341 $(use_enable libnotify notify) \
342 $(use_enable libsamplerate samplerate) \
343 $(use_enable libtar) \
344 $(use_enable libtiger tiger) \
345 $(use_enable linsys) \
346 $(use_enable lirc) \
347 $(use_enable live live555) \
348 $(use_enable lua) \
349 $(use_enable macosx-audio) \
350 $(use_enable macosx-dialog-provider) \
351 $(use_enable macosx-eyetv) \
352 $(use_enable macosx-qtkit) \
353 $(use_enable macosx-quartztext) \
354 $(use_enable macosx-vout) \
355 $(use_enable matroska mkv) \
356 $(use_enable mmx) \
357 $(use_enable modplug mod) \
358 $(use_enable mp3 mad) \
359 $(use_enable mpeg libmpeg2) \
360 $(use_enable mtp) \
361 $(use_enable musepack mpc) \
362 $(use_enable ncurses) \
363 $(use_enable neon) \
364 $(use_enable ogg) $(use_enable ogg mux_ogg) \
365 $(use_enable omxil) \
366 $(use_enable omxil omxil-vout) \
367 $(use_enable opencv) \
368 $(use_enable opengl glx) $(use_enable opengl glspectrum) \
369 $(use_enable opus) \
370 $(use_enable optimisememory optimize-memory) \
371 $(use_enable png) \
372 $(use_enable postproc) \
373 $(use_enable projectm) \
374 $(use_enable pulseaudio pulse) \
375 ${qt_flag} \
376 $(use_enable rdp freerdp) \
377 $(use_enable rtsp realrtsp) \
378 $(use_enable run-as-root) \
379 $(use_enable samba smbclient) \
380 $(use_enable schroedinger) \
381 $(use_enable sdl) \
382 $(use_enable sdl-image) \
383 $(use_enable sid) \
384 $(use_enable sftp) \
385 $(use_enable shout) \
386 $(use_enable skins skins2) \
387 $(use_enable speex) \
388 $(use_enable sse) \
389 $(use_enable svg) \
390 $(use_enable swscale) \
391 $(use_enable taglib) \
392 $(use_enable theora) \
393 $(use_enable tremor) \
394 $(use_enable truetype freetype) \
395 $(use_enable twolame) \
396 $(use_enable udev) \
397 $(use_enable upnp) \
398 $(use_enable v4l v4l2) \
399 $(use_enable vaapi libva) \
400 $(use_enable vcdx) \
401 $(use_enable vdpau) \
402 $(use_enable vlm) \
403 $(use_enable vnc) \
404 $(use_enable vorbis) \
405 $(use_enable vpx) \
406 $(use_enable wma-fixed) \
407 $(use_with X x) \
408 $(use_enable x264) \
409 $(use_enable xcb) \
410 $(use_enable xml libxml2) \
411 $(use_enable xv xvideo) \
412 $(use_enable zvbi) $(use_enable !zvbi telx) \
413 --disable-asdcp \
414 --disable-coregraphicslayer-vout \
415 --disable-coverage \
416 --disable-cprof \
417 --disable-crystalhd \
418 --disable-decklink \
419 --disable-ios-audio \
420 --disable-goom \
421 --disable-kai \
422 --disable-kva \
423 --disable-maintainer-mode \
424 --disable-merge-ffmpeg \
425 --disable-mfx \
426 --disable-opensles \
427 --disable-oss \
428 --disable-quicktime \
429 --disable-rpi-omxil \
430 --disable-shine \
431 --disable-sndio \
432 --disable-x265 \
433 --disable-vda \
434 --disable-vsxu \
435 --disable-wasapi
436
437 # ^ We don't have these disabled libraries in the Portage tree yet.
438 }
439
440 src_test() {
441 Xemake check-TESTS
442 }
443
444 DOCS="AUTHORS THANKS NEWS README doc/fortunes.txt doc/intf-vcd.txt"
445
446 src_install() {
447 default
448
449 # Punt useless libtool's .la files
450 find "${D}" -name '*.la' -delete
451 }
452
453 pkg_postinst() {
454 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
455 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
456 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
457 else
458 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
459 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
460 ewarn "If you do not do it, vlc will take a long time to load."
461 fi
462 }

  ViewVC Help
Powered by ViewVC 1.1.20