/[gentoo-x86]/media-video/vlc/vlc-9999.ebuild
Gentoo

Contents of /media-video/vlc/vlc-9999.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.98 - (show annotations) (download)
Sat Oct 16 17:13:54 2010 UTC (6 years, 6 months ago) by aballier
Branch: MAIN
Changes since 1.97: +1 -5 lines
cleanup old code for snapshots; we'll do it another way if some day there is need for some

(Portage version: 2.2_rc97/cvs/Linux x86_64)

1 # Copyright 1999-2010 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-9999.ebuild,v 1.97 2010/10/16 01:15:49 aballier Exp $
4
5 EAPI="3"
6
7 SCM=""
8 if [ "${PV%9999}" != "${PV}" ] ; then
9 SCM=git
10 EGIT_BOOTSTRAP="bootstrap"
11 EGIT_BRANCH=master
12 EGIT_PROJECT=${P}
13 if [ "${PV%.9999}" != "${PV}" ] ; then
14 EGIT_REPO_URI="git://git.videolan.org/vlc/vlc-${PV%.9999}.git"
15 else
16 EGIT_REPO_URI="git://git.videolan.org/vlc.git"
17 fi
18 fi
19
20 inherit eutils multilib autotools toolchain-funcs gnome2 qt4 flag-o-matic ${SCM}
21
22 MY_PV="${PV/_/-}"
23 MY_PV="${MY_PV/-beta/-test}"
24 MY_P="${PN}-${MY_PV}"
25
26 PATCHLEVEL="89"
27 DESCRIPTION="VLC media player - Video player and streamer"
28 HOMEPAGE="http://www.videolan.org/vlc/"
29 if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
30 SRC_URI=""
31 elif [[ "${MY_P}" == "${P}" ]]; then
32 SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
33 else
34 SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
35 fi
36
37 SRC_URI="${SRC_URI}
38 mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2"
39
40 LICENSE="GPL-2"
41 SLOT="0"
42
43 if [ "${PV%9999}" = "${PV}" ] ; then
44 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
45 else
46 KEYWORDS=""
47 fi
48 IUSE="a52 aac aalib alsa altivec atmo avahi bidi cdda cddb dbus dc1394
49 debug dirac directfb dts dvb dvd elibc_glibc fbcon fluidsynth +ffmpeg flac fontconfig
50 +gcrypt gnome gnutls httpd ieee1394 jack kate kde libass libcaca
51 libnotify libproxy libtiger libv4l2 lirc live lua matroska mmx
52 modplug mp3 mpeg mtp musepack ncurses ogg opengl optimisememory oss
53 png projectm pulseaudio pvr +qt4 remoteosd rtsp run-as-root samba
54 schroedinger sdl sdl-image shine shout skins speex sqlite sse stream
55 svg taglib theora truetype twolame udev upnp v4l2 vaapi vcdx vlm
56 vorbis win32codecs wma-fixed +X x264 +xcb xml xosd xv zvbi"
57
58 RDEPEND="
59 sys-libs/zlib
60 >=media-libs/libdvbpsi-0.1.6
61 a52? ( >=media-libs/a52dec-0.7.4-r3 )
62 aalib? ( media-libs/aalib )
63 aac? ( >=media-libs/faad2-2.6.1 )
64 alsa? ( media-libs/alsa-lib )
65 avahi? ( >=net-dns/avahi-0.6[dbus] )
66 bidi? ( >=dev-libs/fribidi-0.10.4 )
67 cdda? ( cddb? ( >=media-libs/libcddb-1.2.0 ) )
68 dbus? ( >=sys-apps/dbus-1.0.2 )
69 dc1394? ( >=sys-libs/libraw1394-2.0.1 >=media-libs/libdc1394-2.0.2 )
70 dirac? ( >=media-video/dirac-0.10.0 )
71 directfb? ( dev-libs/DirectFB sys-libs/zlib )
72 dts? ( media-libs/libdca )
73 dvd? ( media-libs/libdvdread >=media-libs/libdvdnav-0.1.9 )
74 elibc_glibc? ( >=sys-libs/glibc-2.8 )
75 ffmpeg? ( >=media-video/ffmpeg-0.6 )
76 flac? ( media-libs/libogg >=media-libs/flac-1.1.2 )
77 fluidsynth? ( media-sound/fluidsynth )
78 fontconfig? ( media-libs/fontconfig )
79 gcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
80 gnome? ( gnome-base/gnome-vfs )
81 gnutls? ( >=net-libs/gnutls-1.7.4 >=dev-libs/libgcrypt-1.2.0 )
82 ieee1394? ( >=sys-libs/libraw1394-2.0.1 >=sys-libs/libavc1394-0.5.3 )
83 jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
84 kate? ( >=media-libs/libkate-0.1.1 )
85 libass? ( >=media-libs/libass-0.9.6 media-libs/fontconfig )
86 libcaca? ( >=media-libs/libcaca-0.99_beta14 )
87 libnotify? ( x11-libs/libnotify )
88 libproxy? ( net-libs/libproxy )
89 libtiger? ( media-libs/libtiger )
90 lirc? ( app-misc/lirc )
91 live? ( >=media-plugins/live-2010.10.15 )
92 lua? ( >=dev-lang/lua-5.1 )
93 matroska? ( >=dev-libs/libebml-1.0.0 >=media-libs/libmatroska-1.0.0 )
94 modplug? ( >=media-libs/libmodplug-0.8.8.1 )
95 mp3? ( media-libs/libmad )
96 mpeg? ( >=media-libs/libmpeg2-0.3.2 )
97 mtp? ( >=media-libs/libmtp-1.0.0 )
98 musepack? ( >=media-sound/musepack-tools-444 )
99 ncurses? ( sys-libs/ncurses )
100 ogg? ( media-libs/libogg )
101 opengl? ( virtual/opengl || ( <x11-libs/libX11-1.3.99.901[xcb] >=x11-libs/libX11-1.3.99.901 ) )
102 png? ( media-libs/libpng sys-libs/zlib )
103 projectm? ( media-libs/libprojectm )
104 pulseaudio? ( >=media-sound/pulseaudio-0.9.11
105 !X? ( >=media-sound/pulseaudio-0.9.11[-X] ) )
106 qt4? ( x11-libs/qt-gui:4 x11-libs/qt-core:4 x11-libs/libX11 )
107 remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
108 samba? ( || ( >=net-fs/samba-3.4.6[smbclient] <net-fs/samba-3.4 ) )
109 schroedinger? ( >=media-libs/schroedinger-1.0.6 )
110 sdl? ( >=media-libs/libsdl-1.2.8
111 sdl-image? ( media-libs/sdl-image sys-libs/zlib ) )
112 shout? ( media-libs/libshout )
113 skins? (
114 x11-libs/qt-gui:4 x11-libs/qt-core:4
115 x11-libs/libXext x11-libs/libX11
116 media-libs/freetype media-fonts/dejavu
117 )
118 speex? ( media-libs/speex )
119 sqlite? ( >=dev-db/sqlite-3.6.0:3 )
120 svg? ( >=gnome-base/librsvg-2.9.0 )
121 taglib? ( >=media-libs/taglib-1.5 sys-libs/zlib )
122 theora? ( >=media-libs/libtheora-1.0_beta3 )
123 truetype? ( media-libs/freetype media-fonts/dejavu )
124 twolame? ( media-sound/twolame )
125 udev? ( >=sys-fs/udev-142 )
126 upnp? ( net-libs/libupnp )
127 v4l2? ( libv4l2? ( media-libs/libv4l ) )
128 vaapi? ( x11-libs/libva >=media-video/ffmpeg-0.6 )
129 vcdx? ( >=dev-libs/libcdio-0.78.2 >=media-video/vcdimager-0.7.22 )
130 vorbis? ( media-libs/libvorbis )
131 win32codecs? ( media-libs/win32codecs )
132 X? ( x11-libs/libX11 )
133 x264? ( >=media-libs/x264-0.0.20090923 )
134 xcb? ( x11-libs/libxcb x11-libs/xcb-util )
135 xml? ( dev-libs/libxml2 )
136 xosd? ( x11-libs/xosd )
137 zvbi? ( >=media-libs/zvbi-0.2.25 )
138 "
139
140 DEPEND="${RDEPEND}
141 !!<=media-video/vlc-1.1.99999
142 dvb? ( sys-kernel/linux-headers )
143 kde? ( >=kde-base/kdelibs-4 )
144 v4l2? ( >=sys-kernel/linux-headers-2.6.25 )
145 xcb? ( x11-proto/xproto )
146 dev-util/pkgconfig"
147
148 S="${WORKDIR}/${MY_P}"
149
150 # Displays a warning if the first use flag is set but the second is not
151 vlc_use_needs() {
152 use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
153 }
154
155 # Notify the user that some useflag have been forced on
156 vlc_use_force() {
157 use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
158 }
159
160 # Use when $1 depends strictly on $2
161 # if use $1 then enable $2
162 vlc_use_enable_force() {
163 use $1 && echo "--enable-$2"
164 }
165
166 pkg_setup() {
167 # Useflags we need to forcefuly enable
168 vlc_use_force remoteosd gcrypt
169 vlc_use_force gnutls gcrypt
170 vlc_use_force skins truetype
171 vlc_use_force skins qt4
172 vlc_use_force vlm stream
173 vlc_use_force vaapi ffmpeg
174
175 # Useflags that will be automagically discarded if deps are not met
176 vlc_use_needs bidi truetype
177 vlc_use_needs cddb cdda
178 vlc_use_needs fontconfig truetype
179 vlc_use_needs libv4l2 v4l2
180 vlc_use_needs libtiger kate
181 vlc_use_needs xv xcb
182
183 if use qt4 || use skins ; then
184 qt4_pkg_setup
185 else
186 ewarn "You have disabled the qt4 useflag, ${PN} will not have any"
187 ewarn "graphical interface. Maybe that is not what you want..."
188 fi
189 }
190
191 src_unpack() {
192 unpack ${A}
193 if [ "${PV%9999}" != "${PV}" ] ; then
194 git_src_unpack
195 fi
196 }
197
198 src_prepare() {
199 if [ "${PV%9999}" != "${PV}" ] ; then
200 git_src_prepare
201 fi
202 # Make it build with libtool 1.5
203 rm -f m4/lt* m4/libtool.m4
204
205 EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
206 eautoreconf
207 }
208
209 src_configure() {
210
211 # It would fail if -fforce-addr is used due to too few registers...
212 use x86 && filter-flags -fforce-addr
213
214 econf \
215 --docdir=/usr/share/doc/${PF} \
216 $(use_enable a52) \
217 $(use_enable aalib aa) \
218 $(use_enable aac faad) \
219 $(use_enable alsa) \
220 $(use_enable altivec) \
221 $(use_enable atmo) \
222 $(use_enable avahi bonjour) \
223 $(use_enable bidi fribidi) \
224 $(use_enable cdda vcd) \
225 $(use_enable cddb libcddb) \
226 $(use_enable dbus) $(use_enable dbus dbus-control) \
227 $(use_enable dirac) \
228 $(use_enable directfb) \
229 $(use_enable dc1394) \
230 $(use_enable debug) \
231 $(use_enable dts dca) \
232 $(use_enable dvb) \
233 $(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
234 $(use_enable fbcon fb) \
235 $(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(use_enable ffmpeg swscale) $(use_enable ffmpeg postproc) \
236 $(use_enable flac) \
237 $(use_enable fluidsynth) \
238 $(use_enable fontconfig) \
239 $(use_enable gnome gnomevfs) \
240 $(use_enable gnutls) \
241 $(use_enable httpd) \
242 $(use_enable ieee1394 dv) \
243 $(use_enable jack) \
244 $(use_enable kate) \
245 $(use_with kde kde-solid) \
246 $(use_enable libass) \
247 $(use_enable libcaca caca) \
248 $(use_enable gcrypt libgcrypt) \
249 $(use_enable libnotify notify) \
250 $(use_enable libproxy) \
251 --disable-libtar \
252 $(use_enable libtiger tiger) \
253 $(use_enable libv4l2) \
254 $(use_enable lirc) \
255 $(use_enable live live555) \
256 $(use_enable lua) \
257 $(use_enable matroska mkv) \
258 $(use_enable mmx) \
259 $(use_enable modplug mod) \
260 $(use_enable mp3 mad) \
261 $(use_enable mpeg libmpeg2) \
262 $(use_enable mtp) \
263 $(use_enable musepack mpc) \
264 $(use_enable ncurses) \
265 $(use_enable ogg) \
266 $(use_enable opengl glx) \
267 $(use_enable optimisememory optimize-memory) \
268 $(use_enable oss) \
269 $(use_enable png) \
270 --disable-portaudio \
271 $(use_enable projectm) \
272 $(use_enable pulseaudio pulse) \
273 $(use_enable pvr) \
274 $(use_enable qt4) \
275 $(use_enable remoteosd) \
276 $(use_enable rtsp realrtsp) \
277 $(use_enable run-as-root) \
278 $(use_enable samba smb) \
279 $(use_enable schroedinger) \
280 $(use_enable sdl) \
281 $(use_enable sdl-image) \
282 $(use_enable shine) \
283 $(use_enable shout) \
284 $(use_enable skins skins2) \
285 $(use_enable speex) \
286 $(use_enable sqlite) \
287 $(use_enable sse) \
288 $(use_enable stream sout) \
289 $(use_enable svg) \
290 $(use_enable taglib) \
291 $(use_enable theora) \
292 $(use_enable truetype freetype) \
293 $(use_enable twolame) \
294 $(use_enable udev) \
295 $(use_enable upnp) \
296 $(use_enable v4l2) \
297 $(use_enable vcdx) \
298 $(use_enable vaapi libva) \
299 $(use_enable vlm) \
300 $(use_enable vorbis) \
301 $(use_enable win32codecs loader) \
302 $(use_enable wma-fixed) \
303 $(use_with X x) \
304 $(use_enable x264) \
305 $(use_enable xcb) \
306 $(use_enable xml libxml2) \
307 $(use_enable xosd) \
308 $(use_enable xv xvideo) \
309 $(use_enable zvbi) $(use_enable !zvbi telx) \
310 --disable-snapshot \
311 --disable-growl \
312 --disable-optimizations \
313 --enable-fast-install \
314 $(vlc_use_enable_force vlm sout) \
315 $(vlc_use_enable_force skins qt4) \
316 $(vlc_use_enable_force skins freetype) \
317 $(vlc_use_enable_force remoteosd libgcrypt) \
318 $(vlc_use_enable_force gnutls libgcrypt) \
319 $(vlc_use_enable_force vaapi avcodec)
320 }
321
322 src_install() {
323 emake DESTDIR="${D}" install || die "make install failed"
324
325 dodoc AUTHORS HACKING THANKS NEWS README \
326 doc/fortunes.txt doc/intf-vcd.txt
327
328 # Punt useless libtool's .la files
329 find "${D}" -name '*.la' -delete
330 }
331
332 pkg_postinst() {
333 gnome2_pkg_postinst
334
335 if [ "$ROOT" = "/" ] && [ -x "/usr/$(get_libdir)/vlc/vlc-cache-gen" ] ; then
336 einfo "Running /usr/$(get_libdir)/vlc/vlc-cache-gen on /usr/$(get_libdir)/vlc/plugins/"
337 "/usr/$(get_libdir)/vlc/vlc-cache-gen" -f "/usr/$(get_libdir)/vlc/plugins/"
338 else
339 ewarn "We cannot run vlc-cache-gen (most likely ROOT!=/)"
340 ewarn "Please run /usr/$(get_libdir)/vlc/vlc-cache-gen manually"
341 ewarn "If you do not do it, vlc will take a long time to load."
342 fi
343 }

  ViewVC Help
Powered by ViewVC 1.1.20