/[gentoo-x86]/net-libs/gupnp/gupnp-0.20.13.ebuild
Gentoo

Contents of /net-libs/gupnp/gupnp-0.20.13.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.5 - (show annotations) (download)
Sun Jun 21 08:53:07 2015 UTC (5 years, 5 months ago) by jer
Branch: MAIN
CVS Tags: HEAD
Changes since 1.4: +2 -2 lines
Stable for PPC64 (bug #551814).

(Portage version: 2.2.20/cvs/Linux x86_64, RepoMan options: --ignore-arches, signed Manifest commit with key A792A613)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp/gupnp-0.20.13.ebuild,v 1.4 2015/03/29 11:17:27 jer Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="no"
7 VALA_USE_DEPEND="vapigen"
8 # FIXME: Claims to works with python3 but appears to be wishful thinking
9 PYTHON_COMPAT=( python2_7 )
10 PYTHON_REQ_USE="xml"
11
12 inherit gnome2 multilib-minimal python-r1 vala
13
14 DESCRIPTION="An object-oriented framework for creating UPnP devs and control points"
15 HOMEPAGE="https://wiki.gnome.org/Projects/GUPnP"
16
17 LICENSE="LGPL-2"
18 SLOT="0/4"
19 KEYWORDS="~alpha amd64 ~arm hppa ~ia64 ~ppc ppc64 ~sparc x86"
20 IUSE="connman +introspection kernel_linux networkmanager"
21
22 REQUIRED_USE="${PYTHON_REQUIRED_USE}
23 ?? ( connman networkmanager )"
24
25 RDEPEND="
26 ${PYTHON_DEPS}
27 >=net-libs/gssdp-0.14.7:0=[introspection?,${MULTILIB_USEDEP}]
28 >=net-libs/libsoup-2.48.0:2.4[introspection?,${MULTILIB_USEDEP}]
29 >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
30 >=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
31 || (
32 >=sys-apps/util-linux-2.24.1-r3[${MULTILIB_USEDEP}]
33 <sys-libs/e2fsprogs-libs-1.41.8[${MULTILIB_USEDEP}] )
34 introspection? (
35 >=dev-libs/gobject-introspection-0.6.4
36 $(vala_depend) )
37 connman? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
38 networkmanager? ( >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] )
39 !net-libs/gupnp-vala
40 "
41 DEPEND="${RDEPEND}
42 >=dev-util/gtk-doc-am-1
43 sys-devel/gettext
44 >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
45 "
46
47 src_prepare() {
48 use introspection && vala_src_prepare
49 gnome2_src_prepare
50 }
51
52 multilib_src_configure() {
53 local backend=unix
54 use kernel_linux && backend=linux
55 use connman && backend=connman
56 use networkmanager && backend=network-manager
57
58 ECONF_SOURCE=${S} \
59 gnome2_src_configure \
60 $(multilib_native_use_enable introspection) \
61 --disable-static \
62 --with-context-manager=${backend}
63
64 if multilib_is_native_abi; then
65 ln -s "${S}"/doc/html doc/html || die
66 fi
67 }
68
69 multilib_src_install() {
70 gnome2_src_install
71 }
72
73 multilib_src_install_all() {
74 einstalldocs
75 python_parallel_foreach_impl python_doscript tools/gupnp-binding-tool
76 }

  ViewVC Help
Powered by ViewVC 1.1.20