/[gentoo-x86]/net-libs/neon/neon-0.30.0.ebuild
Gentoo

Contents of /net-libs/neon/neon-0.30.0.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.11 - (show annotations) (download)
Sun Mar 16 02:51:12 2014 UTC (4 years, 8 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.10: +2 -2 lines
Add arm64 love.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/neon/neon-0.30.0.ebuild,v 1.10 2014/01/26 12:22:34 ago Exp $
4
5 EAPI="5"
6
7 inherit autotools libtool
8
9 DESCRIPTION="HTTP and WebDAV client library"
10 HOMEPAGE="http://www.webdav.org/neon/"
11 SRC_URI="http://www.webdav.org/neon/${P}.tar.gz"
12
13 LICENSE="GPL-2"
14 SLOT="0/27"
15 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
16 IUSE="doc expat gnutls kerberos libproxy nls pkcs11 ssl static-libs zlib"
17 IUSE_LINGUAS="cs de fr ja nn pl ru tr zh_CN"
18 for lingua in ${IUSE_LINGUAS}; do
19 IUSE+=" linguas_${lingua}"
20 done
21 unset lingua
22 RESTRICT="test"
23
24 RDEPEND="expat? ( dev-libs/expat:0= )
25 !expat? ( dev-libs/libxml2:2= )
26 gnutls? (
27 app-misc/ca-certificates
28 net-libs/gnutls:0=
29 pkcs11? ( dev-libs/pakchois:0= )
30 )
31 !gnutls? ( ssl? (
32 dev-libs/openssl:0=
33 pkcs11? ( dev-libs/pakchois:0= )
34 ) )
35 kerberos? ( virtual/krb5:0= )
36 libproxy? ( net-libs/libproxy:0= )
37 nls? ( virtual/libintl:0= )
38 zlib? ( sys-libs/zlib:0= )"
39 DEPEND="${RDEPEND}
40 virtual/pkgconfig"
41
42 src_prepare() {
43 local lingua linguas
44 for lingua in ${IUSE_LINGUAS}; do
45 use linguas_${lingua} && linguas+=" ${lingua}"
46 done
47 sed -e "s/ALL_LINGUAS=.*/ALL_LINGUAS=\"${linguas}\"/" -i configure.in
48
49 AT_M4DIR="macros" eautoreconf
50
51 elibtoolize
52 }
53
54 src_configure() {
55 local myconf=()
56
57 if has_version sys-libs/glibc; then
58 einfo "Enabling SSL library thread-safety using POSIX threads..."
59 myconf+=(--enable-threadsafe-ssl=posix)
60 fi
61
62 if use expat; then
63 myconf+=(--with-expat)
64 else
65 myconf+=(--with-libxml2)
66 fi
67
68 if use gnutls; then
69 myconf+=(--with-ssl=gnutls --with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt")
70 elif use ssl; then
71 myconf+=(--with-ssl=openssl)
72 fi
73
74 econf \
75 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
76 --enable-shared \
77 $(use_with kerberos gssapi) \
78 $(use_with libproxy) \
79 $(use_enable nls) \
80 $(use_with pkcs11 pakchois) \
81 $(use_enable static-libs static) \
82 $(use_with zlib) \
83 "${myconf[@]}"
84 }
85
86 src_install() {
87 emake DESTDIR="${D}" install-{config,headers,lib,man,nls}
88
89 find "${ED}" -name "*.la" -delete
90
91 if use doc; then
92 emake DESTDIR="${D}" install-html
93 fi
94
95 dodoc AUTHORS BUGS NEWS README THANKS TODO
96 }

  ViewVC Help
Powered by ViewVC 1.1.20