/[gentoo-x86]/net-libs/neon/neon-0.30.1.ebuild
Gentoo

Contents of /net-libs/neon/neon-0.30.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.11 - (show annotations) (download)
Sat May 16 07:56:57 2015 UTC (5 years, 6 months ago) by vapier
Branch: MAIN
CVS Tags: HEAD
Changes since 1.10: +4 -3 lines
Fix from Chromium OS for cross-compiling.

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/neon/neon-0.30.1.ebuild,v 1.10 2014/12/06 16:41:07 ago Exp $
4
5 EAPI="5"
6
7 inherit autotools libtool multilib-minimal
8
9 DESCRIPTION="HTTP and WebDAV client library"
10 HOMEPAGE="http://www.webdav.org/neon/"
11 SRC_URI="http://www.webdav.org/neon/${P}.tar.gz"
12
13 LICENSE="GPL-2"
14 SLOT="0/27"
15 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
16 IUSE="doc expat gnutls kerberos libproxy nls pkcs11 ssl static-libs zlib"
17 IUSE_LINGUAS="cs de fr ja nn pl ru tr zh_CN"
18 for lingua in ${IUSE_LINGUAS}; do
19 IUSE+=" linguas_${lingua}"
20 done
21 unset lingua
22 RESTRICT="test"
23
24 RDEPEND="expat? ( dev-libs/expat:0=[${MULTILIB_USEDEP}] )
25 !expat? ( dev-libs/libxml2:2=[${MULTILIB_USEDEP}] )
26 gnutls? (
27 app-misc/ca-certificates
28 net-libs/gnutls:0=[${MULTILIB_USEDEP}]
29 pkcs11? ( dev-libs/pakchois:0=[${MULTILIB_USEDEP}] )
30 )
31 !gnutls? ( ssl? (
32 dev-libs/openssl:0=[${MULTILIB_USEDEP}]
33 pkcs11? ( dev-libs/pakchois:0=[${MULTILIB_USEDEP}] )
34 ) )
35 kerberos? ( virtual/krb5:0=[${MULTILIB_USEDEP}] )
36 libproxy? ( net-libs/libproxy:0=[${MULTILIB_USEDEP}] )
37 nls? ( virtual/libintl:0=[${MULTILIB_USEDEP}] )
38 zlib? ( sys-libs/zlib:0=[${MULTILIB_USEDEP}] )"
39 DEPEND="${RDEPEND}
40 virtual/pkgconfig[${MULTILIB_USEDEP}]"
41 RDEPEND="${RDEPEND}
42 abi_x86_32? (
43 !<=app-emulation/emul-linux-x86-baselibs-20140508-r8
44 !app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
45 )"
46
47 MULTILIB_CHOST_TOOLS=(
48 /usr/bin/neon-config
49 )
50
51 src_prepare() {
52 local lingua linguas
53 for lingua in ${IUSE_LINGUAS}; do
54 use linguas_${lingua} && linguas+=" ${lingua}"
55 done
56 sed -e "s/ALL_LINGUAS=.*/ALL_LINGUAS=\"${linguas}\"/" -i configure.ac || die
57
58 epatch "${FILESDIR}"/${P}-xml2-config.patch
59 AT_M4DIR="macros" eautoreconf
60
61 elibtoolize
62
63 multilib_copy_sources
64 }
65
66 multilib_src_configure() {
67 local myconf=()
68
69 if has_version sys-libs/glibc; then
70 einfo "Enabling SSL library thread-safety using POSIX threads..."
71 myconf+=(--enable-threadsafe-ssl=posix)
72 fi
73
74 if use expat; then
75 myconf+=(--with-expat)
76 else
77 myconf+=(--with-libxml2)
78 fi
79
80 if use gnutls; then
81 myconf+=(--with-ssl=gnutls --with-ca-bundle="${EPREFIX}/etc/ssl/certs/ca-certificates.crt")
82 elif use ssl; then
83 myconf+=(--with-ssl=openssl)
84 fi
85
86 econf \
87 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
88 --enable-shared \
89 $(use_with kerberos gssapi) \
90 $(use_with libproxy) \
91 $(use_enable nls) \
92 $(use_with pkcs11 pakchois) \
93 $(use_enable static-libs static) \
94 $(use_with zlib) \
95 "${myconf[@]}"
96 }
97
98 multilib_src_install() {
99 emake DESTDIR="${D}" install-{config,headers,lib,man,nls}
100
101 if multilib_is_native_abi && use doc; then
102 dohtml -r doc/html/
103 fi
104 }
105
106 multilib_src_install_all() {
107 find "${ED}" -name "*.la" -delete
108
109 dodoc AUTHORS BUGS NEWS README THANKS TODO
110 }

  ViewVC Help
Powered by ViewVC 1.1.20