/[gentoo-x86]/net-libs/xrootd/xrootd-4.1.1.ebuild
Gentoo

Contents of /net-libs/xrootd/xrootd-4.1.1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Sat Feb 28 04:33:34 2015 UTC (5 years, 8 months ago) by bircoph
Branch: MAIN
CVS Tags: HEAD
version bump

Signed-off-by: Andrew Savchenko <bircoph@gentoo.org>
(Portage version: 2.2.17/cvs/Linux i686, signed Manifest commit with key 565953B95372756C)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-libs/xrootd/xrootd-4.0.0.ebuild,v 1.1 2014/06/19 18:13:17 bicatali Exp $
4
5 EAPI=5
6
7 inherit cmake-utils eutils user multilib
8
9 DURI="http://xrootd.slac.stanford.edu/doc/prod"
10
11 DESCRIPTION="Extended ROOT remote file server"
12 HOMEPAGE="http://xrootd.org/"
13 SRC_URI="${HOMEPAGE}/download/v${PV}/${P}.tar.gz"
14
15 LICENSE="LGPL-3"
16 SLOT="0"
17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
18 IUSE="doc fuse http kerberos libevent perl readline ssl test"
19
20 RDEPEND="
21 !<sci-physics/root-5.32[xrootd]
22 sys-libs/zlib:0=
23 fuse? ( sys-fs/fuse:0= )
24 kerberos? ( virtual/krb5 )
25 libevent? ( dev-libs/libevent[threads] )
26 perl? (
27 dev-lang/perl
28 readline? ( dev-perl/Term-ReadLine-Perl )
29 )
30 readline? ( sys-libs/readline:0= )
31 ssl? ( dev-libs/openssl:0= )"
32 DEPEND="${RDEPEND}
33 doc? ( app-doc/doxygen[dot] )
34 perl? ( dev-lang/swig )
35 test? ( dev-util/cppunit )"
36
37 REQUIRED_USE="
38 http? ( kerberos ssl )"
39
40 PATCHES=( "${FILESDIR}"/${PN}-no-werror.patch )
41
42 pkg_setup() {
43 enewgroup xrootd
44 enewuser xrootd -1 -1 "${EPREFIX}"/var/spool/xrootd xrootd
45 }
46
47 src_configure() {
48 local mycmakeargs=(
49 $(cmake-utils_use_enable fuse)
50 $(cmake-utils_use_enable http)
51 $(cmake-utils_use_enable kerberos KRB5)
52 $(cmake-utils_use_enable libevent)
53 $(cmake-utils_use_enable perl)
54 $(cmake-utils_use_enable readline)
55 $(cmake-utils_use_enable ssl CRYPTO)
56 $(cmake-utils_use_enable test TESTS)
57 )
58 cmake-utils_src_configure
59 }
60
61 src_compile() {
62 cmake-utils_src_compile
63 use doc && doxygen Doxyfile
64 }
65
66 src_install() {
67 cmake-utils_src_install
68
69 # base configs
70 insinto /etc/xrootd
71 doins packaging/common/*.cfg
72
73 fowners root:xrootd /etc/xrootd
74 keepdir /var/log/xrootd
75 fowners xrootd:xrootd /var/log/xrootd
76
77 local i
78 for i in cmsd frm_purged frm_xfrd xrootd; do
79 newinitd "${FILESDIR}"/${i}.initd ${i}
80 done
81 # all daemons MUST use single master config file
82 newconfd "${FILESDIR}"/xrootd.confd xrootd
83
84 dodoc docs/ReleaseNotes.txt
85 use doc && dohtml -r doxydoc/html/*
86 }

  ViewVC Help
Powered by ViewVC 1.1.20