/[gentoo-x86]/net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild
Gentoo

Contents of /net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Wed Nov 26 01:00:24 2014 UTC (5 years, 3 months ago) by floppym
Branch: MAIN
Changes since 1.2: +2 -2 lines
Remove directfb from IUSE.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

1 # Copyright 1999-2014 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/freerdp/freerdp-1.2.0_beta1_pre20141115.ebuild,v 1.2 2014/11/26 00:04:20 floppym Exp $
4
5 EAPI="5"
6
7 inherit cmake-utils vcs-snapshot
8
9 if [[ ${PV} != 9999* ]]; then
10 COMMIT="7a6c6b7436c2fcb02a38bf89e0b3efcdb43f2ef5"
11 SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
12 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
13 else
14 inherit git-r3
15 SRC_URI=""
16 EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
17 https://github.com/FreeRDP/FreeRDP.git"
18 fi
19
20 DESCRIPTION="Free implementation of the Remote Desktop Protocol"
21 HOMEPAGE="http://www.freerdp.com/"
22
23 LICENSE="Apache-2.0"
24 SLOT="0/1.2"
25 IUSE="alsa +client cups debug doc ffmpeg gstreamer jpeg
26 pulseaudio server smartcard sse2 test usb X xinerama xv"
27
28 RDEPEND="
29 dev-libs/openssl
30 sys-libs/zlib
31 alsa? ( media-libs/alsa-lib )
32 cups? ( net-print/cups )
33 client? (
34 usb? (
35 virtual/libudev:0=
36 sys-apps/util-linux:0=
37 dev-libs/dbus-glib:0=
38 virtual/libusb:1=
39 )
40 X? (
41 x11-libs/libXcursor
42 x11-libs/libXext
43 x11-libs/libXi
44 x11-libs/libXrender
45 xinerama? ( x11-libs/libXinerama )
46 xv? ( x11-libs/libXv )
47 )
48 )
49 ffmpeg? ( virtual/ffmpeg )
50 gstreamer? (
51 media-libs/gstreamer:1.0
52 media-libs/gst-plugins-base:1.0
53 x11-libs/libXrandr
54 )
55 jpeg? ( virtual/jpeg )
56 pulseaudio? ( media-sound/pulseaudio )
57 server? (
58 X? (
59 x11-libs/libXcursor
60 x11-libs/libXdamage
61 x11-libs/libXext
62 x11-libs/libXfixes
63 xinerama? ( x11-libs/libXinerama )
64 )
65 )
66 smartcard? ( sys-apps/pcsc-lite )
67 X? (
68 x11-libs/libX11
69 x11-libs/libxkbfile
70 )
71 "
72 DEPEND="${RDEPEND}
73 virtual/pkgconfig
74 client? ( X? ( doc? (
75 app-text/docbook-xml-dtd:4.1.2
76 app-text/xmlto
77 ) ) )
78 "
79
80 DOCS=( README )
81
82 src_configure() {
83 local mycmakeargs=(
84 $(cmake-utils_use_with alsa ALSA)
85 $(cmake-utils_use_with client CLIENT)
86 $(cmake-utils_use_with cups CUPS)
87 $(cmake-utils_use_with debug DEBUG_ALL)
88 $(cmake-utils_use_with doc MANPAGES)
89 $(cmake-utils_use_with ffmpeg FFMPEG)
90 $(cmake-utils_use_with gstreamer GSTREAMER_1_0)
91 $(cmake-utils_use_with jpeg JPEG)
92 $(cmake-utils_use_with pulseaudio PULSE)
93 $(cmake-utils_use_with server SERVER)
94 $(cmake-utils_use_with smartcard PCSC)
95 $(cmake-utils_use_with sse2 SSE2)
96 $(cmake-utils_use usb CHANNEL_URBDRC)
97 $(cmake-utils_use_with X X11)
98 $(cmake-utils_use_with xinerama XINERAMA)
99 $(cmake-utils_use_with xv XV)
100 $(cmake-utils_use_build test TESTING)
101 )
102 cmake-utils_src_configure
103 }

  ViewVC Help
Powered by ViewVC 1.1.20