/[gentoo-x86]/net-misc/mediatomb/mediatomb-0.12.1-r6.ebuild
Gentoo

Contents of /net-misc/mediatomb/mediatomb-0.12.1-r6.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.4 - (show annotations) (download)
Tue Dec 17 23:39:27 2013 UTC (5 years, 11 months ago) by thev00d00
Branch: MAIN
CVS Tags: HEAD
Changes since 1.3: +1 -1 lines
FILE REMOVED
Bump to -r7, tidy up ebuild, remove old, add flac and youtube patches, epatch_user #467110 #494398

(Portage version: 2.2.7/cvs/Linux x86_64, unsigned Manifest commit)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/mediatomb/mediatomb-0.12.1-r6.ebuild,v 1.3 2013/08/26 15:31:14 axs Exp $
4
5 EAPI=5
6 inherit autotools eutils linux-info user
7
8 DEB_VER="4"
9 DESCRIPTION="MediaTomb is an open source UPnP MediaServer"
10 HOMEPAGE="http://www.mediatomb.cc/"
11 SRC_URI="mirror://sourceforge/mediatomb/${P}.tar.gz
12 mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}-${DEB_VER}.debian.tar.gz"
13
14 LICENSE="GPL-2"
15 SLOT="0"
16 KEYWORDS="~amd64 ~arm ~ppc ~x86"
17 IUSE="+curl debug +exif +ffmpeg id3tag inotify +javascript lastfm libextractor +magic +mp4 mysql +sqlite +taglib thumbnail +zlib"
18 REQUIRED_USE="
19 || ( mysql sqlite )
20 taglib? ( !id3tag ) id3tag? ( !taglib )
21 thumbnail? ( ffmpeg !libextractor )
22 ffmpeg? ( !libextractor )
23 libextractor? ( !ffmpeg !thumbnail )
24 "
25
26 DEPEND="mysql? ( virtual/mysql )
27 id3tag? ( media-libs/id3lib )
28 javascript? ( >=dev-lang/spidermonkey-1.8.5:0 )
29 dev-libs/expat
30 taglib? ( media-libs/taglib )
31 sqlite? ( >=dev-db/sqlite-3 )
32 lastfm? ( >=media-libs/lastfmlib-0.4 )
33 exif? ( media-libs/libexif )
34 libextractor? ( media-libs/libextractor )
35 mp4? ( >=media-libs/libmp4v2-1.9.1_p479:0 )
36 ffmpeg? ( virtual/ffmpeg )
37 thumbnail? ( media-video/ffmpegthumbnailer[jpeg] )
38 curl? ( net-misc/curl )
39 magic? ( sys-apps/file )
40 sys-apps/util-linux
41 zlib? ( sys-libs/zlib )
42 virtual/libiconv"
43 RDEPEND="${DEPEND}"
44
45 CONFIG_CHECK="~INOTIFY_USER"
46
47 pkg_setup() {
48 enewgroup mediatomb
49 enewuser mediatomb -1 -1 /dev/null mediatomb
50 }
51
52 src_prepare() {
53 local p dd="${WORKDIR}"/debian/patches
54 sed -i -r '/^[-+]{3} /s:[.][.]/::' "${dd}"/* || die
55 for p in $(<"${dd}"/series) ; do
56 epatch "${dd}"/${p}
57 done
58 epatch "${FILESDIR}"/${P}-libmp4v2.patch
59 epatch "${FILESDIR}"/${P}-system-uuid.patch #270830
60 if has_version "~dev-lang/spidermonkey-1.8.7" ; then
61 epatch "${FILESDIR}"/${P}-mozjs187.patch #435394
62 fi
63 epatch "${FILESDIR}"/${P}-libextractor.patch #435394
64 epatch "${FILESDIR}"/${P}-inotify-hard-links.patch
65 epatch "${FILESDIR}"/${P}-thumb-cache.patch
66 epatch "${FILESDIR}"/${P}-libav9.patch
67 epatch "${FILESDIR}"/${P}-avformatcontext-pointer.patch #446922
68 epatch "${FILESDIR}"/${P}-system-ar.patch
69 eautoreconf
70 }
71
72 src_configure() {
73 econf \
74 $(use_enable curl) $(use_enable curl youtube) \
75 $(use_enable debug tombdebug) \
76 $(use_enable exif libexif) \
77 $(use_enable ffmpeg) \
78 $(use_enable id3tag id3lib) \
79 $(use_enable inotify) \
80 $(use_enable javascript libjs) \
81 $(use_enable lastfm lastfmlib) \
82 $(use_enable libextractor) \
83 $(use_enable magic libmagic) \
84 $(use_enable mp4 libmp4v2) \
85 $(use_enable mysql) \
86 $(use_enable sqlite sqlite3) \
87 $(use_enable taglib) \
88 $(use_enable thumbnail ffmpegthumbnailer) \
89 $(use_enable zlib) \
90 --enable-external-transcoding \
91 --enable-protocolinfo-extension
92 }
93
94 src_install() {
95 default
96
97 newinitd "${FILESDIR}"/${PN}-0.12.1.initd ${PN}
98 use mysql || sed -i -e "/use mysql/d" "${ED}"/etc/init.d/${PN}
99 newconfd "${FILESDIR}"/${PN}-0.12.0.confd ${PN}
100
101 insinto /etc/mediatomb
102 newins "${FILESDIR}/${PN}-0.12.0.config" config.xml
103 fperms 0600 /etc/mediatomb/config.xml
104 fowners mediatomb:mediatomb /etc/mediatomb/config.xml
105
106 keepdir /var/lib/mediatomb
107 fowners mediatomb:mediatomb /var/lib/mediatomb
108 }
109
110 pkg_postinst() {
111 if use mysql ; then
112 elog "MediaTomb has been built with MySQL support and needs"
113 elog "to be configured before being started."
114 elog "For more information, please consult the MediaTomb"
115 elog "documentation: http://mediatomb.cc/pages/documentation"
116 elog
117 fi
118
119 elog "To configure MediaTomb edit:"
120 elog "/etc/mediatomb/config.xml"
121 elog
122 elog "The MediaTomb web interface can be reached at (after the service is started):"
123 elog "http://localhost:49152/"
124 }

  ViewVC Help
Powered by ViewVC 1.1.20