/[gentoo-x86]/net-misc/nx/nx-3.2.0-r5.ebuild
Gentoo

Contents of /net-misc/nx/nx-3.2.0-r5.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Mon Sep 15 14:58:29 2008 UTC (11 years, 1 month ago) by voyageur
Branch: MAIN
Add patch for nxproxy to read from stdin, allows nxcl to use standard ssh instead of nxssh
(Portage version: 2.2_rc8/cvs/Linux 2.6.26-gentoo x86_64)

1 voyageur 1.1 # Copyright 1999-2008 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: /var/cvsroot/gentoo-x86/net-misc/nx/nx-3.2.0-r4.ebuild,v 1.1 2008/08/26 08:50:56 voyageur Exp $
4    
5     inherit autotools eutils multilib
6    
7     DESCRIPTION="NX compression technology core libraries"
8     HOMEPAGE="http://www.nomachine.com/developers.php"
9    
10     URI_BASE="http://web04.nomachine.com/download/${PV}/sources"
11     SRC_NX_X11="nx-X11-$PV-2.tar.gz"
12     SRC_NXAGENT="nxagent-$PV-10.tar.gz"
13     SRC_NXAUTH="nxauth-$PV-1.tar.gz"
14     SRC_NXCOMP="nxcomp-$PV-7.tar.gz"
15     SRC_NXCOMPEXT="nxcompext-$PV-1.tar.gz"
16     SRC_NXCOMPSHAD="nxcompshad-$PV-3.tar.gz"
17     SRC_NXPROXY="nxproxy-$PV-1.tar.gz"
18    
19     SRC_URI="$URI_BASE/$SRC_NX_X11 $URI_BASE/$SRC_NXAGENT $URI_BASE/$SRC_NXPROXY $URI_BASE/$SRC_NXAUTH $URI_BASE/$SRC_NXCOMPEXT $URI_BASE/$SRC_NXCOMPSHAD $URI_BASE/$SRC_NXCOMP"
20    
21     LICENSE="GPL-2"
22     SLOT="0"
23     KEYWORDS="~amd64 ~x86"
24     IUSE="rdesktop vnc"
25    
26     RDEPEND="x11-libs/libXau
27     x11-libs/libXcomposite
28     x11-libs/libXdamage
29     x11-libs/libXdmcp
30     x11-libs/libXpm
31     x11-libs/libXrandr
32     x11-libs/libXtst
33     >=media-libs/jpeg-6b-r4
34     >=media-libs/libpng-1.2.8
35     >=sys-libs/zlib-1.2.3
36     rdesktop? ( net-misc/rdesktop )
37     vnc? ( || ( net-misc/vnc net-misc/tightvnc ) )"
38    
39     DEPEND="${RDEPEND}
40     x11-misc/gccmakedep
41     x11-misc/imake
42     x11-proto/inputproto"
43    
44     S=${WORKDIR}/${PN}-X11
45    
46     pkg_setup() {
47     if use vnc; then
48     if has_version net-misc/vnc && ! built_with_use net-misc/vnc server;
49     then
50     die "net-misc/vnc needs to be built with USE=\"server\" for VNC support"
51     fi
52    
53     if has_version net-misc/tightvnc && ! built_with_use net-misc/tightvnc server;
54     then
55     die "net-misc/tightvnc needs to be built with USE=\"server\" for VNC support"
56     fi
57     fi
58     }
59    
60     src_unpack() {
61     unpack ${A}
62    
63     cd "${WORKDIR}"
64     epatch "${FILESDIR}"/1.5.0/nx-x11-1.5.0-tmp-exec.patch
65     epatch "${FILESDIR}"/1.5.0/nxcomp-1.5.0-pic.patch
66    
67     cd "${WORKDIR}"/nxproxy
68     epatch "${FILESDIR}"/${P}-nxproxy_read_from_stdin.patch
69    
70     cd "${WORKDIR}"/nxcomp
71     epatch "${FILESDIR}"/${PN}-2.1.0-invalid-options.patch
72     eautoreconf
73     }
74    
75     src_compile() {
76     cd "${WORKDIR}"/nxcomp || die "No nxcomp directory found"
77     econf || die "nxcomp econf failed"
78     emake || die "nxcomp emake failed"
79    
80     cd "${WORKDIR}"/nxcompshad || die "No nxcompshad directory found"
81    
82     econf || die "nxcompshad econf failed"
83     emake || die "nxcompshad emake failed"
84    
85     cd "${WORKDIR}"/nxproxy || die "No nxproxy directory found"
86     econf || die "nxproxy econf failed"
87     emake || die "nxproxy emake failed"
88    
89     cd "${S}" || die "No nx-X11 directory found"
90     emake World || die "nx-X11 emake failed"
91    
92     cd "${WORKDIR}"/nxcompext || die "No nxcompext directory found"
93     econf || die "nxcompext econf failed"
94     emake || die "nxcompext emake failed"
95     }
96    
97     src_install() {
98     NX_ROOT=/usr/$(get_libdir)/NX
99    
100     for x in nxagent nxauth nxproxy; do
101     make_wrapper $x ./$x ${NX_ROOT}/bin ${NX_ROOT}/$(get_libdir) ||
102     die " $x wrapper creation failed"
103     done
104    
105     into ${NX_ROOT}
106     dobin "${S}"/programs/Xserver/nxagent
107     dobin "${S}"/programs/nxauth/nxauth
108     dobin "${WORKDIR}"/nxproxy/nxproxy
109    
110     dolib.so "${S}"/lib/X11/libX11.so*
111     dolib.so "${S}"/lib/Xext/libXext.so*
112     dolib.so "${S}"/lib/Xrender/libXrender.so*
113     dolib.so "${WORKDIR}"/nxcomp/libXcomp.so*
114     dolib.so "${WORKDIR}"/nxcompext/libXcompext.so*
115     dolib.so "${WORKDIR}"/nxcompshad/libXcompshad.so*
116     }

  ViewVC Help
Powered by ViewVC 1.1.20