/[gentoo-x86]/net-misc/olsrd/olsrd-0.6.4-r1.ebuild
Gentoo

Contents of /net-misc/olsrd/olsrd-0.6.4-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (hide annotations) (download)
Sat Jun 1 23:03:33 2013 UTC (6 years, 9 months ago) by pinkbyte
Branch: MAIN
Revision bump: EAPI 5, fix minor QA issues, set proper prefix, wrt bug #453440, drop old broken revision

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

1 pinkbyte 1.1 # Copyright 1999-2013 Gentoo Foundation
2     # Distributed under the terms of the GNU General Public License v2
3     # $Header: /var/cvsroot/gentoo-x86/net-misc/olsrd/olsrd-0.6.4.ebuild,v 1.1 2012/11/15 16:50:37 jer Exp $
4    
5     EAPI=5
6     inherit eutils multilib toolchain-funcs versionator
7    
8     MY_PV="$(replace_version_separator 3 '-r')"
9     DESCRIPTION="An implementation of the Optimized Link State Routing protocol"
10     HOMEPAGE="http://www.olsr.org/"
11     SRC_URI="http://www.olsr.org/releases/$(get_version_component_range 1-2)/${PN}-${MY_PV}.tar.bz2"
12    
13     SLOT="0"
14     LICENSE="BSD LGPL-2.1"
15     KEYWORDS="~amd64 ~x86"
16     IUSE="gtk"
17     DEPEND="
18     gtk? (
19     dev-libs/glib:2
20     x11-libs/gdk-pixbuf:2
21     x11-libs/gtk+:2
22     )
23     "
24     RDEPEND="${DEPEND}"
25     S="${WORKDIR}/${PN}-${MY_PV}"
26    
27     src_prepare() {
28     epatch \
29     "${FILESDIR}/${PN}-0.6.1-build_fix.patch" \
30     "${FILESDIR}/${PN}-0.6.3-make-gtk.patch"
31    
32     # fix parallel make
33     # respect AR
34     # verbose build
35     # fix default prefix, bug #453440
36     sed -i \
37     -e '/@echo "\[/d' \
38     -e 's|$(MAKECMD)|$(MAKE)|g' \
39     -e 's|@$(CC)|$(CC)|g' \
40     -e 's|@ar |$(AR) |g' \
41     -e '/^prefix/s:/usr/local:/usr:' \
42     $( find . -name 'Makefile*' ) || die
43    
44     # respect LDFLAGS
45     sed -i \
46     -e 's|$(CC)|& $(OLSRD_LDFLAGS)|g' \
47     lib/pud/nmealib/Makefile lib/pud/wireformat/Makefile || die
48     }
49    
50     src_compile() {
51     emake \
52     CC="$(tc-getCC)" \
53     LIBDIR="/usr/$(get_libdir)/${PN}" \
54     OLSRD_LDFLAGS="${LDFLAGS}" \
55     OS=linux \
56     build_all
57     if use gtk; then
58     emake -C "${S}/gui/linux-gtk" LIBDIR="/usr/$(get_libdir)/${PN}" CC="$(tc-getCC)"
59     fi
60     }
61    
62     src_install() {
63     emake OS=linux LIBDIR="${D}/usr/$(get_libdir)/${PN}" \
64     DESTDIR="${D}" STRIP=true install_all
65     if use gtk; then
66     emake -C "${S}/gui/linux-gtk" \
67     LIBDIR="${D}/usr/$(get_libdir)/${PN}" DESTDIR="${D}" install
68     fi
69    
70     doinitd "${FILESDIR}/${PN}"
71    
72     dodoc CHANGELOG \
73     valgrind-howto.txt files/olsrd.conf.default.rfc \
74     files/olsrd.conf.default.lq files/olsrd.conf.default.lq-fisheye \
75     lib/arprefresh/README_ARPREFRESH \
76     lib/bmf/README_BMF \
77     lib/dot_draw/README_DOT_DRAW \
78     lib/dyn_gw/README_DYN_GW \
79     lib/dyn_gw_plain/README_DYN_GW_PLAIN \
80     lib/httpinfo/README_HTTPINFO \
81     lib/mini/README_MINI \
82     lib/nameservice/README_NAMESERVICE \
83     lib/pgraph/README_PGRAPH \
84     lib/quagga/README_QUAGGA \
85     lib/secure/README_SECURE \
86     lib/txtinfo/README_TXTINFO \
87     lib/watchdog/README_WATCHDOG
88     }

  ViewVC Help
Powered by ViewVC 1.1.20