/[gentoo-x86]/net-misc/pump/pump-0.8.24-r4.ebuild
Gentoo

Contents of /net-misc/pump/pump-0.8.24-r4.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.10 - (show annotations) (download)
Sat Jun 1 21:42:55 2013 UTC (6 years, 6 months ago) by pinkbyte
Branch: MAIN
CVS Tags: HEAD
Changes since 1.9: +3 -2 lines
Add workaround to epatch call to make sure that patches are applied in right order, wrt bug #471666. Thanks to Pavel Riha for discovering this issue and Jeroen Roovers for suggested patch

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/pump/pump-0.8.24-r4.ebuild,v 1.9 2013/02/22 17:25:23 ago Exp $
4
5 EAPI=5
6
7 inherit eutils toolchain-funcs
8
9 PATCHLEVEL="7"
10
11 DESCRIPTION="This is the DHCP/BOOTP client written by RedHat"
12 HOMEPAGE="http://ftp.debian.org/debian/pool/main/p/pump/"
13 SRC_URI="mirror://debian/pool/main/p/${PN}/${PN}_${PV}.orig.tar.gz
14 mirror://debian/pool/main/p/${PN}/${PN}_${PV}-${PATCHLEVEL}.diff.gz"
15
16 LICENSE="GPL-2"
17 SLOT="0"
18 KEYWORDS="amd64 arm hppa ia64 ppc sparc x86"
19 IUSE=""
20
21 DEPEND=">=dev-libs/popt-1.5"
22 RDEPEND="${DEPEND}"
23
24 src_prepare() {
25 # Fix Debian patch to fit epatch logic
26 sed -i \
27 -e 's:/debian::g' \
28 -e '/^---/s:pump-0.8.24.orig/::' \
29 -e '/^+++/s:pump-0.8.24/::' \
30 "${WORKDIR}/${PN}_${PV}-${PATCHLEVEL}.diff" || die "sed on ${PN}_${PV}-${PATCHLEVEL}.diff failed"
31
32 # Apply Debians pump patchset - they fix things good :)
33 # Debian patchset 7 include gentoo patchset too
34 epatch "${WORKDIR}/${PN}_${PV}-${PATCHLEVEL}.diff"
35 # Add LC_ALL workaround to make sure that patches are applied in right order(bug 471666)
36 LC_ALL=C EPATCH_FORCE="yes" EPATCH_SOURCE="patches" EPATCH_SUFFIX="patch" epatch
37
38 # respect AR, wrt bug #458482
39 tc-export AR
40
41 epatch_user
42 }
43
44 src_compile() {
45 emake CC="$(tc-getCC)" DEB_CFLAGS="-fPIC ${CFLAGS}" pump
46 }
47
48 src_install() {
49 exeinto /sbin
50 doexe pump
51
52 doman pump.8
53 dodoc changelog CREDITS
54
55 dolib.a libpump.a
56 doheader pump.h
57 }

  ViewVC Help
Powered by ViewVC 1.1.20