/[gentoo-x86]/net-misc/vinagre/vinagre-3.14.3-r1.ebuild
Gentoo

Contents of /net-misc/vinagre/vinagre-3.14.3-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.3 - (show annotations) (download)
Fri Jun 26 09:23:51 2015 UTC (4 years, 3 months ago) by ago
Branch: MAIN
CVS Tags: HEAD
Changes since 1.2: +2 -2 lines
Stable for x86, wrt bug #551814

(Portage version: 2.2.18/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 7194459F)

1 # Copyright 1999-2015 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/vinagre/vinagre-3.14.3-r1.ebuild,v 1.2 2015/06/21 13:54:28 zlogene Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="no"
7 VALA_MIN_API_VERSION=0.18
8
9 inherit gnome2 linux-info vala
10
11 DESCRIPTION="VNC client for the GNOME desktop"
12 HOMEPAGE="https://wiki.gnome.org/Apps/Vinagre"
13
14 LICENSE="GPL-3+"
15 SLOT="0"
16 KEYWORDS="amd64 ~arm ~ia64 ~ppc ~ppc64 x86"
17 IUSE="rdp +ssh spice +telepathy zeroconf"
18
19 # cairo used in vinagre-tab
20 # gdk-pixbuf used all over the place
21 RDEPEND="
22 >=dev-libs/glib-2.28.0:2
23 >=x11-libs/gtk+-3.9.6:3
24 app-crypt/libsecret
25 >=dev-libs/libxml2-2.6.31:2
26 >=net-libs/gtk-vnc-0.4.3[gtk3]
27 x11-libs/cairo:=
28 x11-libs/gdk-pixbuf:2
29 x11-themes/hicolor-icon-theme
30
31 rdp? ( net-misc/freerdp )
32 ssh? ( >=x11-libs/vte-0.20:2.91 )
33 spice? (
34 app-emulation/spice-protocol
35 >=net-misc/spice-gtk-0.5[gtk3] )
36 telepathy? (
37 dev-libs/dbus-glib
38 >=net-libs/telepathy-glib-0.11.6 )
39 zeroconf? ( >=net-dns/avahi-0.6.26[dbus,gtk3] )
40 "
41 DEPEND="${RDEPEND}
42 >=dev-lang/perl-5
43 dev-libs/appstream-glib
44 >=dev-util/intltool-0.50
45 >=sys-devel/gettext-0.17
46 virtual/pkgconfig
47 $(vala_depend)
48 "
49
50 pkg_pretend() {
51 # Needed for VNC ssh tunnel, bug #518574
52 CONFIG_CHECK="~IPV6"
53 check_extra_config
54 }
55
56 src_prepare() {
57 # Fix RDP initialization with recent FreeRDP (from 'master')
58 epatch "${FILESDIR}"/${PN}-3.14.3-freerdp.patch
59 epatch "${FILESDIR}"/${PN}-3.14.3-freerdp2.patch
60
61 vala_src_prepare
62 gnome2_src_prepare
63 }
64
65 src_configure() {
66 DOCS="AUTHORS ChangeLog ChangeLog.pre-git NEWS README"
67 gnome2_src_configure \
68 $(use_enable rdp) \
69 $(use_enable ssh) \
70 $(use_enable spice) \
71 $(use_with telepathy) \
72 $(use_with zeroconf avahi) \
73 ITSTOOL=$(type -P true)
74 }

  ViewVC Help
Powered by ViewVC 1.1.20