/[gentoo-x86]/net-misc/vino/vino-3.8.1-r1.ebuild
Gentoo

Contents of /net-misc/vino/vino-3.8.1-r1.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.1 - (show annotations) (download)
Fri Sep 13 22:41:08 2013 UTC (6 years, 1 month ago) by eva
Branch: MAIN
Apply a security fix. Clean up old revisions.

(Portage version: 2.2.4/cvs/Linux x86_64, signed Manifest commit with key C6085806)

1 # Copyright 1999-2013 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/vino/vino-3.8.1.ebuild,v 1.1 2013/04/19 18:04:49 pacho Exp $
4
5 EAPI="5"
6 GCONF_DEBUG="yes"
7
8 inherit eutils gnome2
9
10 DESCRIPTION="An integrated VNC server for GNOME"
11 HOMEPAGE="http://live.gnome.org/Vino"
12
13 LICENSE="GPL-2+"
14 SLOT="0"
15 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
16 IUSE="avahi crypt gnome-keyring ipv6 jpeg networkmanager ssl +telepathy +zlib"
17
18 # cairo used in vino-fb
19 # libSM and libICE used in eggsmclient-xsmp
20 RDEPEND="
21 >=dev-libs/glib-2.26:2
22 >=x11-libs/gtk+-3.0.0:3
23 >=dev-libs/libgcrypt-1.1.90:0=
24 >=net-libs/libsoup-2.24:2.4
25
26 dev-libs/dbus-glib
27 x11-libs/cairo:=
28 x11-libs/pango[X]
29 x11-libs/libICE
30 x11-libs/libX11
31 x11-libs/libXdamage
32 x11-libs/libXext
33 x11-libs/libXfixes
34 x11-libs/libSM
35 x11-libs/libXtst
36
37 >=x11-libs/libnotify-0.7.0:=
38
39 avahi? ( >=net-dns/avahi-0.6:=[dbus] )
40 crypt? ( >=dev-libs/libgcrypt-1.1.90:0= )
41 gnome-keyring? ( app-crypt/libsecret )
42 jpeg? ( virtual/jpeg:0= )
43 networkmanager? ( >=net-misc/networkmanager-0.7 )
44 ssl? ( >=net-libs/gnutls-2.2.0:= )
45 telepathy? ( >=net-libs/telepathy-glib-0.18.0 )
46 zlib? ( sys-libs/zlib:= )
47 "
48 DEPEND="${RDEPEND}
49 >=dev-lang/perl-5
50 >=dev-util/intltool-0.50
51 virtual/pkgconfig
52 app-crypt/libsecret"
53 # libsecret is always required at build time per bug 322763
54
55 # bug #394611; tight encoding requires zlib encoding
56 REQUIRED_USE="jpeg? ( zlib )"
57
58 src_prepare() {
59 # Apply upstream patch as announced on distributor list
60 # will be in 3.8.2/3.10
61 epatch "${FILESDIR}"/${P}-new-client.patch
62
63 # <glib-2.31 compatibility
64 rm -v server/vino-marshal.{c,h} || die
65 gnome2_src_prepare
66 }
67
68 src_configure() {
69 gnome2_src_configure \
70 --enable-http-server \
71 --with-gcrypt \
72 $(use_with avahi) \
73 $(use_with crypt gcrypt) \
74 $(use_enable ipv6) \
75 $(use_with jpeg) \
76 $(use_with gnome-keyring secret) \
77 $(use_with networkmanager network-manager) \
78 $(use_with ssl gnutls) \
79 $(use_with telepathy) \
80 $(use_with zlib)
81 }

  ViewVC Help
Powered by ViewVC 1.1.20