/[gentoo-x86]/net-misc/whois/whois-5.0.20.ebuild
Gentoo

Contents of /net-misc/whois/whois-5.0.20.ebuild

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1.2 - (show annotations) (download)
Wed May 28 14:12:05 2014 UTC (6 years, 4 months ago) by polynomial-c
Branch: MAIN
CVS Tags: HEAD
Changes since 1.1: +1 -1 lines
FILE REMOVED
Version bump. Removed old

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

1 # Copyright 1999-2012 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3 # $Header: /var/cvsroot/gentoo-x86/net-misc/whois/whois-5.0.20.ebuild,v 1.1 2012/10/16 16:41:53 radhermit Exp $
4
5 EAPI=4
6 inherit eutils toolchain-funcs
7
8 MY_P=${P/-/_}
9 DESCRIPTION="improved Whois Client"
10 HOMEPAGE="http://www.linux.it/~md/software/"
11 SRC_URI="mirror://debian/pool/main/w/whois/${MY_P}.tar.xz"
12
13 LICENSE="GPL-2"
14 SLOT="0"
15 KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux"
16 IUSE="iconv idn nls"
17 RESTRICT="test" #59327
18
19 RDEPEND="iconv? ( virtual/libiconv )
20 idn? ( net-dns/libidn )
21 nls? ( virtual/libintl )"
22 DEPEND="${RDEPEND}
23 app-arch/xz-utils
24 >=dev-lang/perl-5
25 nls? ( sys-devel/gettext )"
26
27 src_prepare() {
28 epatch "${FILESDIR}"/${PN}-4.7.2-config-file.patch
29
30 if use nls ; then
31 sed -i -e 's:#\(.*pos\):\1:' Makefile || die
32 else
33 sed -i -e '/ENABLE_NLS/s:define:undef:' config.h || die
34
35 # don't generate po files when nls is disabled (bug #419889)
36 sed -i -e '/^all:/s/ pos//' \
37 -e '/^install:/s/ install-pos//' Makefile || die
38 fi
39 }
40
41 src_configure() { :;} # expected no-op
42
43 src_compile() {
44 unset HAVE_ICONV HAVE_LIBIDN
45 use iconv && export HAVE_ICONV=1
46 use idn && export HAVE_LIBIDN=1
47 tc-export CC
48 emake CFLAGS="${CFLAGS} ${CPPFLAGS}"
49 }
50
51 src_install() {
52 emake BASEDIR="${ED}" prefix=/usr install
53 insinto /etc
54 doins whois.conf
55 dodoc README debian/changelog
56
57 if [[ ${USERLAND} != "GNU" ]]; then
58 mv "${ED}"/usr/share/man/man1/{whois,mdwhois}.1 || die
59 mv "${ED}"/usr/bin/{whois,mdwhois} || die
60 fi
61 }

  ViewVC Help
Powered by ViewVC 1.1.20