summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorZac Medico <zmedico@gentoo.org>2015-02-24 23:43:32 +0000
committerZac Medico <zmedico@gentoo.org>2015-02-24 23:43:32 +0000
commit05f06e36e03b3ca8a63d6b88b32bd89156ad993c (patch)
tree4f500cbdd78385cc4d9c4fd79e45ac0170fbbc3b /dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild
parentBumb revision for bug 541284, for anyone who may have it installed in the wro... (diff)
downloadhistorical-05f06e36e03b3ca8a63d6b88b32bd89156ad993c.tar.gz
historical-05f06e36e03b3ca8a63d6b88b32bd89156ad993c.tar.bz2
historical-05f06e36e03b3ca8a63d6b88b32bd89156ad993c.zip
Bumb revision for bug 541284, for anyone who may have it installed in the wrong place.
Package-Manager: portage-2.2.17/cvs/Linux x86_64 Manifest-Sign-Key: 0xAE5719A3
Diffstat (limited to 'dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild')
-rw-r--r--dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild51
1 files changed, 51 insertions, 0 deletions
diff --git a/dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild b/dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild
new file mode 100644
index 000000000000..7c9b70955cd2
--- /dev/null
+++ b/dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/go-fuse/go-fuse-0_p20140812-r1.ebuild,v 1.1 2015/02/24 23:43:26 zmedico Exp $
+
+EAPI=5
+
+KEYWORDS="~amd64"
+RESTRICT="strip"
+DESCRIPTION="FUSE bindings for Go"
+GO_PN=github.com/hanwen/${PN}
+HOMEPAGE="https://${GO_PN}"
+EGIT_COMMIT="8c85ded140ac1889372a0e22d8d21e3d10a303bd"
+SRC_URI="https://${GO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+LICENSE="BSD"
+SLOT="0"
+IUSE=""
+DEPEND=">=dev-lang/go-1.3"
+RDEPEND=""
+S=${WORKDIR}
+
+src_unpack() {
+ default_src_unpack
+ mkdir -p src/${GO_PN%/*} || die
+ mv ${PN}-${EGIT_COMMIT} src/${GO_PN} || die
+}
+
+src_prepare() {
+ sed -e "s:\(go \${target}\)\(.*\)$:\\1 -x \\2:" \
+ -e 's:^for target in "clean" "install" ; do$:for target in "install" ; do:' \
+ -e '17,26d' \
+ src/${GO_PN}/all.bash > src/${GO_PN}/all.bash.patched || die
+}
+
+src_compile() {
+ # Create a filtered GOROOT tree out of symlinks,
+ # excluding go-fuse, for bug #503324.
+ cp -sR /usr/lib/go goroot || die
+ rm -rf goroot/src/${GO_PN} || die
+ rm -rf goroot/pkg/linux_${ARCH}/${GO_PN} || die
+ CGO_CFLAGS="${CFLAGS}" GOROOT="${WORKDIR}/goroot" GOPATH="${WORKDIR}" \
+ bash src/${GO_PN}/all.bash.patched || die
+}
+
+src_install() {
+ insinto /usr/lib/go
+ doins -r pkg
+ insinto /usr/lib/go/src
+ rm src/${GO_PN}/all.bash.patched || die
+ find src/${GO_PN} -name .gitignore -delete
+ doins -r src/*
+}