summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJulian Ospald <hasufell@gentoo.org>2013-09-23 23:55:24 +0000
committerJulian Ospald <hasufell@gentoo.org>2013-09-23 23:55:24 +0000
commit517f2f0304188dda853a9f6fcb2e85e6cd87d82f (patch)
tree8eb444f75ba2b2be80c5e99c7c94c7ed5b02854a /net-firewall/pglinux/pglinux-2.2.2-r1.ebuild
parentVersion bump (diff)
downloadhistorical-517f2f0304188dda853a9f6fcb2e85e6cd87d82f.tar.gz
historical-517f2f0304188dda853a9f6fcb2e85e6cd87d82f.tar.bz2
historical-517f2f0304188dda853a9f6fcb2e85e6cd87d82f.zip
add systemd support wrt #485674
Package-Manager: portage-2.2.6/cvs/Linux x86_64 Manifest-Sign-Key: 0xE73C35B3
Diffstat (limited to 'net-firewall/pglinux/pglinux-2.2.2-r1.ebuild')
-rw-r--r--net-firewall/pglinux/pglinux-2.2.2-r1.ebuild106
1 files changed, 106 insertions, 0 deletions
diff --git a/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild b/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild
new file mode 100644
index 000000000000..ab046b47c195
--- /dev/null
+++ b/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/pglinux/pglinux-2.2.2-r1.ebuild,v 1.1 2013/09/23 23:55:18 hasufell Exp $
+
+EAPI=5
+
+inherit autotools eutils gnome2-utils linux-info systemd
+
+MY_P="pgl-${PV}"
+
+DESCRIPTION="Privacy oriented firewall application"
+HOMEPAGE="https://sourceforge.net/projects/peerguardian/"
+SRC_URI="mirror://sourceforge/peerguardian/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="cron dbus logrotate networkmanager qt4 zlib"
+
+COMMON_DEPEND="
+ net-libs/libnetfilter_queue
+ net-libs/libnfnetlink
+ dbus? ( sys-apps/dbus )
+ zlib? ( sys-libs/zlib )
+ qt4? ( sys-auth/polkit-qt
+ dev-qt/qtcore:4
+ dev-qt/qtdbus:4
+ dev-qt/qtgui:4
+ || ( kde-base/kdesu x11-libs/gksu x11-misc/ktsuss )
+ )"
+DEPEND="${COMMON_DEPEND}
+ virtual/pkgconfig
+ sys-devel/libtool:2"
+RDEPEND="${COMMON_DEPEND}
+ net-firewall/iptables
+ sys-apps/sysvinit
+ cron? ( virtual/cron )
+ logrotate? ( app-admin/logrotate )
+ networkmanager? ( net-misc/networkmanager )"
+
+REQUIRED_USE="qt4? ( dbus )"
+
+CONFIG_CHECK="~NETFILTER_NETLINK
+ ~NETFILTER_NETLINK_QUEUE
+ ~NETFILTER_XTABLES
+ ~NETFILTER_XT_TARGET_NFQUEUE
+ ~NETFILTER_XT_MATCH_IPRANGE
+ ~NETFILTER_XT_MARK
+ ~NETFILTER_XT_MATCH_MULTIPORT
+ ~NETFILTER_XT_MATCH_STATE
+ ~NF_CONNTRACK
+ ~NF_CONNTRACK_IPV4
+ ~NF_DEFRAG_IPV4
+ ~IP_NF_FILTER
+ ~IP_NF_IPTABLES
+ ~IP_NF_TARGET_REJECT"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+ epatch -p2 "${FILESDIR}"/${P}-path-variables.patch \
+ "${FILESDIR}"/{0,1}-${P}-gentoo-init.patch \
+ "${FILESDIR}"/{0..6}-${P}-systemd.patch
+
+ eautoreconf
+}
+
+src_configure() {
+ econf \
+ --localstatedir=/var \
+ --docdir=/usr/share/doc/${PF} \
+ $(use_enable logrotate) \
+ $(use_enable cron) \
+ $(use_enable networkmanager) \
+ $(use_enable zlib) \
+ $(use_enable dbus) \
+ --disable-lowmem \
+ --with-iconsdir=/usr/share/icons/hicolor/128x128/apps \
+ --with-gentoo-init \
+ $(use_with qt4) \
+ --with-systemd="$(systemd_get_unitdir)"
+}
+
+src_install() {
+ default
+ keepdir /var/{lib,log,spool}/pgl
+ rm -rf "${ED}"/tmp
+}
+
+pkg_preinst() {
+ gnome2_icon_savelist
+}
+
+pkg_postinst() {
+ elog "optional dependencies:"
+ elog " app-arch/p7zip (needed for blocklists packed as .7z)"
+ elog " app-arch/unzip (needed for blocklists packed as .zip)"
+ elog " virtual/mta (needed to send informational (blocklist updates) and"
+ elog " warning mails (if pglcmd.wd detects a problem.))"
+
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+}