summaryrefslogtreecommitdiff
blob: 27bf4ec39ba3efb7318fac5c38ec8be2695ab84f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/log4c/log4c-1.2.4.ebuild,v 1.1 2014/10/15 17:47:58 kensington Exp $

EAPI=5

inherit autotools-utils

DESCRIPTION="Log4c is a library of C for flexible logging to files, syslog and other destinations"
HOMEPAGE="http://log4c.sourceforge.net/"
SRC_URI="mirror://sourceforge/log4c/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc examples +expat static-libs"

RDEPEND="expat? ( dev-libs/expat )"
DEPEND="${RDEPEND}
	doc? ( 	app-doc/doxygen[dot] )"

PATCHES=( "${FILESDIR}/${P}-docdir.patch" )

src_configure() {
	local myeconfargs=(
		--disable-expattest
		$(use_enable debug)
		$(use_enable doc)
	)

	use expat || myeconfargs+=( --without-expat )

	autotools-utils_src_configure
}

src_install() {
	autotools-utils_src_install

	if use examples; then
		insinto "/usr/share/doc/${PF}/examples"
		doins -r examples/*
	fi
}