aboutsummaryrefslogtreecommitdiff
blob: d2b2683792d72db63992f9a8030fdb03bb009f2f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DESCRIPTION="A software PKCS#11 implementation"
HOMEPAGE="https://www.opendnssec.org/"
SRC_URI="https://www.opendnssec.org/files/source/${P}.tar.gz"

KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
IUSE="bindist gost migration-tool test"
RESTRICT="!test? ( test )"
SLOT="2"
LICENSE="BSD"

RDEPEND="migration-tool? ( dev-db/sqlite:3= )
	dev-libs/openssl:0=[bindist=]
	!~dev-libs/softhsm-2.0.0:0"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig
	sys-devel/gcc:=[cxx]
	test? ( dev-util/cppunit )"

DOCS=(
	NEWS
	README.md
)

PATCHES=(
	"${FILESDIR}/${P}-libressl.patch"
)

src_configure() {
	econf \
		--disable-static \
		--with-crypto-backend=openssl \
		--disable-p11-kit \
		--localstatedir="${EROOT}/var" \
		$(use_enable !bindist ecc) \
		$(use_enable gost) \
		$(use_with migration-tool migrate)
}

src_install() {
	default
	find "${D}" -name '*.la' -delete || die

	keepdir "${EROOT}/var/lib/softhsm/tokens"
}