summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorSam James <sam@gentoo.org>2021-09-20 00:45:58 +0100
committerSam James <sam@gentoo.org>2021-09-20 00:45:58 +0100
commitfe8437d0490377fc23c02c522517fdc1becceea3 (patch)
treebcf9ea37c4d9a69baa8265b6b3eb97b69e3d5101
parentmedia-libs/smpeg2: Stabilize 2.0.0-r4 sparc, #813780 (diff)
downloadgentoo-fe8437d0490377fc23c02c522517fdc1becceea3.tar.gz
gentoo-fe8437d0490377fc23c02c522517fdc1becceea3.tar.bz2
gentoo-fe8437d0490377fc23c02c522517fdc1becceea3.zip
sys-kernel/gentoo-kernel-bin: add 5.14.6-r1 for arm64
Signed-off-by: Sam James <sam@gentoo.org>
-rw-r--r--sys-kernel/gentoo-kernel-bin/Manifest1
-rw-r--r--sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.6-r1.ebuild113
2 files changed, 114 insertions, 0 deletions
diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 22acdb8cc206..4577466a64ef 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -91,6 +91,7 @@ DIST gentoo-kernel-5.13.19-1.amd64.xpak 67338326 BLAKE2B d9e718a94bf9a341f5b5706
DIST gentoo-kernel-5.13.19-1.arm64.xpak 62747957 BLAKE2B 1981ddb4e35d2210e1c678856ac58e088cd100ecbd70d2b5c88ffe8eb25b56f3f0c90e45d12adb74c7a0fb881dfd36b1d46d6fdfb837dbdff1881ded066b906d SHA512 d8c1e524a3e58def5352b3faae07c42074a2d67015cc62b9601e20bb9b7f29d44d2843e7771e0399e9150be1de2be2b28776f96f7fe75ba7ec4e8f2c31e1f715
DIST gentoo-kernel-5.13.19-1.x86.xpak 58517020 BLAKE2B 1dcd347af7693696f93f7a28326aff4c7936c4b71238500b6dd2a4b7cd2b88891436c7c8b7c6a56f638182b722ba5e75f52a1befc74eef4bfe9e6f6fd7d8ef8e SHA512 7bf1cf45d06cf4c6331d8d0c0378d253f6760dbd2f564cac6f7e53d30748ea01ea2d96a6c409a0d653ed74366d319e28ae1e2924b07f4ce7899c5bae121a3630
DIST gentoo-kernel-5.14.6-1.amd64.xpak 68042594 BLAKE2B e65f4a2fc48c0d5989e6b5eebfb6d26d97ca0772fa40cdae0591d264544fcc7ef8575a230bc4a74277dc3136cbb5ad9f95fbf7c1dbaeb2615022c43fc505ffff SHA512 36cb5b165c29e1dff1cc6ec062f99a5e566050dfe83d696384d43f93767bb1a8b2914d92f2a1bcf8dc5b61947bf2b2586ba05f37833f8666ec6849509aac8bbc
+DIST gentoo-kernel-5.14.6-1.arm64.xpak 63383231 BLAKE2B f3aaf70951c5d4e67d4488fe762db4750a6c212638625c5b10ef075711ceb32f0f43a3011ccc11c5e1d3937616d9ba285f21ac6d1dcef02071c6bff62d0286b4 SHA512 b5a0d0740f408c1db8ffdd5ff546457148e7472fa93f56814a51a2dab85a24753aae5c96b8d4e01abc812d1544a502efcffe0e8b5d93feca2fb5743ac9f098f7
DIST gentoo-kernel-5.14.6-1.x86.xpak 59165165 BLAKE2B b376b096789549da8fb39bd6d0fd294e09d1c23b83dec963c14a1fc45ae81bd296d7de91721ff7722af12feb3547d2d8d415025d5c573a8ae35b7edee61f9937 SHA512 1c5ec62b7de43a8337496868781d44be96b846c159e7f14a382a442fbb2dd6cc49a95686302705d5d8e30eb92aea397dd18eb0da4c1183692bdc159c07502b72
DIST gentoo-kernel-5.4.142-1.amd64.xpak 61382010 BLAKE2B 5753309c6f0e98adf348b332ef8acad749f0501b5a0641f2436c7ca7a48c6e57d9f2b316f06d82b5e362cbdf91aa253ba69c7425b6eda0db46531e04929ac6de SHA512 c8433c79fde6bc7b31ff2d93b24e5b327166dcf00157ef91057b006b071f6c7293940285c54f282d40a09957f91831dac9f622dd477be62ec8fea713b0a6b68e
DIST gentoo-kernel-5.4.142-1.arm64.xpak 58037550 BLAKE2B f2f047abcfc83ed15154c617a10810c3d608106d47e8ddd7f5a70e8b3d5a77e6df34b56efeacbcd14fd479db3f7c5574026bdf4d2c6910dd8e9bb5940f4443c7 SHA512 8a9f109738071ae08ea7231964d1fda529aa5bb0810e96c19b3b82c1743868545eb254fc0604586c10645583012baaa0d2a2e930e460ba0697102b081d277521
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.6-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.6-r1.ebuild
new file mode 100644
index 000000000000..c4534b7e4c4d
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.6-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+ https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+ https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+ https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+ arm64? (
+ https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+ -> ${BINPKG}.arm64.xpak
+ )"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+ !sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+ >=virtual/dist-kernel-${PV}"
+BDEPEND="
+ sys-devel/bc
+ sys-devel/flex
+ virtual/libelf
+ virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+ default
+ ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+ tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+ eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+ local PATCHES=(
+ # meh, genpatches have no directory
+ "${WORKDIR}"/*.patch
+ )
+ cd "${MY_P}" || die
+ default
+}
+
+src_configure() {
+ # force ld.bfd if we can find it easily
+ local LD="$(tc-getLD)"
+ if type -P "${LD}.bfd" &>/dev/null; then
+ LD+=.bfd
+ fi
+
+ tc-export_build_env
+ local makeargs=(
+ V=1
+
+ HOSTCC="$(tc-getBUILD_CC)"
+ HOSTCXX="$(tc-getBUILD_CXX)"
+ HOSTCFLAGS="${BUILD_CFLAGS}"
+ HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+ CROSS_COMPILE=${CHOST}-
+ AS="$(tc-getAS)"
+ CC="$(tc-getCC)"
+ LD="${LD}"
+ AR="$(tc-getAR)"
+ NM="$(tc-getNM)"
+ STRIP=":"
+ OBJCOPY="$(tc-getOBJCOPY)"
+ OBJDUMP="$(tc-getOBJDUMP)"
+
+ # we need to pass it to override colliding Gentoo envvar
+ ARCH=$(tc-arch-kernel)
+
+ O="${WORKDIR}"/modprep
+ )
+
+ mkdir modprep || die
+ cp "usr/src/linux-${KPV}/.config" modprep/ || die
+ emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+ kernel-install_test "${KPV}" \
+ "${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+ "lib/modules/${KPV}"
+}
+
+src_install() {
+ mv lib usr "${ED}"/ || die
+
+ # strip out-of-source build stuffs from modprep
+ # and then copy built files
+ find modprep -type f '(' \
+ -name Makefile -o \
+ -name '*.[ao]' -o \
+ '(' -name '.*' -a -not -name '.config' ')' \
+ ')' -delete || die
+ rm modprep/source || die
+ cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}